Ublox Neo-7 Gps Tracking System With Qubitro And Arduino Mkr

Photo of radhyahmad

Made by radhyahmad / Communication / Displays / Sensors / Wearables / IoT

About the project

GPS tracking system based on Qubitro IoT Paltform

Project info

Difficulty: Moderate

Platforms: Adafruit, Arduino, PlatformIO

Estimated time: 4 hours

License: Apache License 2.0 (Apache-2.0)

Items used in this project

Hardware components

	BME280 Breakout - Temperature, Pressure, Humidity Sensor	x 1
	Ublox GPS	x 1
	Arduino MKR1010	x 1

Software apps and online services

PlatformIO

Story

In this project, we will implement remote monitoring via Arduino MKR 1010 to sense the environment and to track location using a GPS module and free public MQTT cloud which is operated and maintained by https://www.qubitro.com/ ( Qubitro is a modern IoT platform where developers can design and develop IoT projects through the user-friendly portal and programmable APIs without worrying about infrastructure management and scalability ).

And also use Arduino in PlatformIO to program Arduino MKR1010. We use sensor BME280 for sensing environment (air temperature, humidity, and pressure) and Ublox Neo-7 GPS for tracking location.

We could read https://docs.qubitro.com/ for detail setup using Qubitro IoT platform.

Required Components:

Arduino MKR 1010

PlatformIO https://platformio.org/

BME280 environment sensor

Qubitro Cloud

Breadboard Electronic

USB Cable

Arduino MKR 1010 Connection Diagram:

Schematics, diagrams and documents

Code

Ublox Neo-7 GPS Tracking System with Qubitro and Arduino MKR

#include <Arduino.h>
#include <SPI.h>
#include <WiFiNINA.h>
#include <ArduinoJson.h>
#include <QubitroMqttClient.h>
#include <Wire.h>
#include <Adafruit_Sensor.h>
#include <Adafruit_BME280.h>
#include <TinyGPS++.h>

void initialize_sensor();
void initialize_wifi();
void initialize_qubitro();
void receivedMessage(int messageSize);
void update_data();

struct dataSense
{
  float temperature = 0.0F;
  float humidity = 0.0F;
  float pressure = 0.0F;
};

struct dataGPS
{
  double latitude = 0.0F;
  double longitude = 0.0F;
};

static char payload[256];
static dataSense data_sensor;
static dataGPS data_gps;
StaticJsonDocument<256> doc;

WiFiClient net;
QubitroMqttClient mqttClient(net);

char ssid[] = "";   
char pass[] = "";

char deviceID[] = "";
char deviceToken[] = "";
char host[] = "broker.qubitro.com";
int port = 1883;

TinyGPSPlus gps;
Adafruit_BME280 bme;

void setup() {

  Serial.begin(9600);
  Serial1.begin(9600);
  initialize_sensor();
  initialize_wifi();
  initialize_qubitro();

}

void loop() {

  if (WiFi.status() != WL_CONNECTED)
  {
    initialize_wifi();
  }
  
  mqttClient.poll();
  update_data();
  
}

void initialize_sensor()
{
  Wire.begin();
  unsigned status;

  status = bme.begin();

  if (!status)
  {
    Serial.println("Could not find a valid BME280.");
    while(1) delay(10);
  }
  
}

void initialize_wifi(){
  delay(100);
  WiFi.disconnect();
  Serial.println();
  Serial.print("Firmware version: ");
  Serial.println(WiFi.firmwareVersion());
  Serial.print("Connecting WiFi to: ");
  Serial.println(ssid);

  while(WiFi.status() != WL_CONNECTED)
  {
    WiFi.begin(ssid, pass);
    Serial.print("Attempting WiFi connection .....");
    
    if (WiFi.status() == WL_CONNECTED)
    {
      Serial.println("WiFi connected");
      Serial.println("IP address: ");
      Serial.println(WiFi.localIP());
      Serial.println("\nWiFi RSSI: ");
      Serial.println(WiFi.RSSI());
      digitalWrite(LED_BUILTIN, HIGH);
    }

    else
    {
      Serial.print("Failed to connect to WiFi");
      Serial.println(", Try again in 5 seconds");
      digitalWrite(LED_BUILTIN, LOW);
      delay(5000);
    }
    
  }
  
}

void initialize_qubitro()
{
  mqttClient.setId(deviceID);
  mqttClient.setDeviceIdToken(deviceID, deviceToken);

  Serial.println("Connecting to Qubitro....");

  if (!mqttClient.connect(host, port))
  {
    Serial.println("Connection failed! Error code= ");
    Serial.println(mqttClient.connectError());
    while(1);
  }
  Serial.println("Connected to Qubitro!");
  mqttClient.onMessage(receivedMessage);
  mqttClient.subscribe(deviceID);
  
}

void receivedMessage(int messageSize) 
{
  Serial.print("New message received:");

  while (mqttClient.available()) 
  {
    Serial.print((char)mqttClient.read());
  }
  Serial.println();
}

void update_data()
{
  float t = bme.readTemperature();
  float h = bme.readHumidity();
  float p = bme.readPressure()/100.0F;

  data_sensor.temperature = t;
  data_sensor.humidity = h;
  data_sensor.pressure = p;

  while(Serial1.available() > 0){

    if(gps.encode(Serial1.read())){
  
      if(gps.location.isValid())
      {
        double latitude  = gps.location.lat();
        double longitude = gps.location.lng();

        data_gps.latitude = latitude;
        data_gps.longitude = longitude;

        doc["Latitute"] = data_gps.latitude;
        doc["Longitude"] = data_gps.longitude;
        doc["Temperature"] = data_sensor.temperature;
        doc["Humidity"] = data_sensor.humidity;
        doc["Pressure"] = data_sensor.pressure;

        serializeJsonPretty(doc, payload);
        mqttClient.beginMessage(deviceID);
        mqttClient.println(payload);
        mqttClient.endMessage();
        //Serial.println(payload);
        delay(5000);
      }

      else
      {
        Serial.println(F("INVALID "));
      }
    }
  }

}

Credits

Photo of radhyahmad

radhyahmad

IoT Engineer and Master Student in ITB Indonesia

Leave your feedback...