Early Warning Detection For Landslide

Photo of radhyahmad

Made by radhyahmad / Astronomy / Displays / Environmental Sensing / Sensors / Sustainability

About the project

Arduino Nano 33 IoT for Early Warning Detection for Landslide Integrated with IoT Qubitro Platfrom.

Project info

Difficulty: Moderate

Platforms: Arduino

Estimated time: 4 days

License: GNU General Public License, version 3 or later (GPL3+)

Items used in this project

Hardware components

Arduino Nano 33 IoT

Arduino Nano 33 IoT

x 1

Software apps and online services

	PlatformIO
	IoT Qubitro Platform

Story

This project is aimed to use IoT standard protocol MQTT and IoT Qubitro Platform to build an analytic model, with an Arduino Nano 33 IoT to collect data related to landslide movement patterns (vertical, horizontal, idle, and fault). It has been made by programming with Arduino IDE, MQTT IoT Qubitro, and WiFiNINA library to connect to the MQTT broker. We could send the data to the IoT Qubitro cloud in real-time, which is able to visualize raw data of sensors.

A network sensor system consists of MCU (Arduino 33 IoT) Dev Kit as data acquisition that collects and processes raw data of sensors, and embedded WiFi module as internet connectivity, and an integrated LSM6DS3 which is an accelerometer and gyroscope sensor. The implementation has been connected to a Qubitro MQTT broker, and Qubitro cloud. Also, it has been used to visualize data analytics on Qubitro portal to build a model to classify the patterns of landslides.

Schematics, diagrams and documents

Early Warning Detection for Landslide

Code

Early Warning Detection for Landslide

#include <Arduino.h>
#include <SPI.h>
#include <Wire.h>
#include <Arduino_LSM6DS3.h>
#include <ArduinoJson.h>
#include <QubitroMqttClient.h>
#include <WiFiNINA.h>

#define CONVERT_G_TO_MS2 9.80665f

void receivedMessage(int messageSize);  

static char payload[256];
//static senseData data;
StaticJsonDocument<256> doc;

#define PERIOD 5000

WiFiClient wifiClient;
QubitroMqttClient mqtt(wifiClient);

const char* ssid = "";
const char* password = "";
char deviceID[] = "";
char deviceToken[] = "";
char host[] = "broker.qubitro.com";
int port = 1883;
unsigned long next = 0;

void receivedMessage(int messageSize) 
{
  Serial.print("New message received:");

  while (mqtt.available()) 
  {
    Serial.print((char)mqtt.read());
  }
  Serial.println();
}

void setup() {

  Serial.begin(9600);
  while (!Serial);
  
  if (!IMU.begin())
  {
    Serial.println("Failed to initialize IMU!");
    while(1);
  }

  Serial.print("Connecting to WiFi...");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)
  {
    Serial.print(".");
    delay(1000);
  }

  Serial.println("\tConnected to the WiFi!");

  mqtt.setId(deviceID);
  mqtt.setDeviceIdToken(deviceID, deviceToken);

  Serial.println("Connecting to Qubitro...");

  if (!mqtt.connect(host, port))
  {
    Serial.println("Connection failed! Error code = ");
    Serial.println(mqtt.connectError());
    while(1);
  }

  Serial.println("Connected to the Qubitro!");
  mqtt.onMessage(receivedMessage);
  mqtt.subscribe(deviceID);
  
}

void loop() {

  mqtt.poll();

  if (millis() > next)
  {
    float acc_x, acc_y, acc_z;
    float gyr_x, gyr_y, gyr_z;

    if (IMU.accelerationAvailable() && IMU.gyroscopeAvailable())
    {
      IMU.readAcceleration(acc_x, acc_y, acc_z);
      
      doc["ACC_X"] = acc_x * CONVERT_G_TO_MS2;
      doc["ACC_Y"] = acc_y * CONVERT_G_TO_MS2;
      doc["ACC_Z"] = acc_z * CONVERT_G_TO_MS2;

      IMU.readGyroscope(gyr_x, gyr_y, gyr_z);

      doc["GYR_X"] = gyr_x;
      doc["GYR_Y"] = gyr_y;
      doc["GYR_Z"] = gyr_z;

      serializeJsonPretty(doc, payload);

      next = millis() + PERIOD;
      mqtt.beginMessage(deviceID);

      //send value
      mqtt.print(payload);
      mqtt.endMessage();

    }
    
  }
  
}

Credits

Photo of radhyahmad

radhyahmad

IoT Engineer and Master Student in ITB Indonesia

Leave your feedback...